能量潮指标，英文简称OBV，是On Balance Volume的缩写。OBV指标结合涨跌情况，对成交量进行处理。本文结合MACD与OBV，用OBV进行改进MACD指标公式。

一、能量潮(OBV)指标解析

在通达信中，OBV的名称是累积能量线，公式如下：

M:=30;

VA:=IF(CLOSE>REF(CLOSE,1),VOL,-VOL);

OBV:SUM(IF(CLOSE=REF(CLOSE,1),0,VA),0);

MAOBV:MA(OBV,M);

1、VA:=IF(CLOSE>REF(CLOSE,1),VOL,-VOL);

这一句表示今天收盘价大于昨天的收盘价，VA为正的成交量VOL；今天的收盘价小于昨天的收盘价，VA为负的成交量-VOL。

2、OBV:SUM(IF(CLOSE=REF(CLOSE,1),0,VA),0);

这一句需要拆开看，IF(CLOSE=REF(CLOSE,1),0,VA)表示今天收盘价等于昨天的收盘价，结果为0；不等于时，结果为VA。OBV:SUM(IF(CLOSE=REF(CLOSE,1),0,VA),0);这一整句表示统计从上市第一天以来的结果的总和。

VA和OBV分开写，解释起来有点云里雾里。其实没那么难，公式把今天收盘价与昨天的收盘价结果分成了三种情况，简单表述如下：

今天是上涨，结果VOL；

今天是下跌，结果是-VOL；

今天不涨不跌，结果是0。

这样每天根据上涨下跌的情况，都有一个结果，OBV就是把上市以来每天的结果加起来。

比如新股上市5天，

第一天上涨，成交量10000，结果是10000；

第二天下跌，成交量8000，结果是-8000；

第三天上涨，成交量8000，结果是8000；

第四天下跌，成交量6000，结果是-6000；

第五天下跌，成交量5000，结果是-5000。

那么，

第一天OBV没有数据，因为上市第一天，没有前一天收盘价数据；

第二天OBV=-8000；

第三天OBV=-8000+8000=0；

第四天OBV=-8000+8000-6000=-6000；

第五天OBV=-8000+8000-6000-5000=-11000。

把这几天的OBV连起来，就是OBV指标中的白线。（如下图）

理解之后，可以把OBV直接写成一句，不使用VA这个中间变量。

OBV:SUM(IF(CLOSE>REF(CLOSE,1),VOL,IF(CLOSE

3、MAOBV:MA(OBV,M);

表示OBV的均线，即OBV指标中的黄线（如下图），指标默认的M为30，MAOBV就是30天OBV均线。30天均线需要有30天的OBV数据，所以一开始MAOBV没有数据，不显示。

二、MACD与OBV结合指标公式

思路：MACD金叉信号比较多，用OBV来过滤。最近30个周期，至少25个周期OBV在MAOBV均线之上，但是不能离得太远。最近5个周期，OBV都在MAOBV之上。满足这些条件，DIF、DEA金叉发出信号。

DIF:EMA(C,12)-EMA(C,26);

DEA:EMA(DIF,9);

MACD:(DIF-DEA)*2,COLORSTICK;

VA:=IF(C>REF(C,1),VOL,-VOL);

OBV:=SUM(IF(C=REF(C,1),0,VA),0);

MAOBV:=MA(OBV,30);

OBVTJ:=BETWEEN(OBV,MAOBV,MAOBV*1.03);{OBV位于MAOBV和1.03倍MAOBV之间}

A1:=COUNT(OBVTJ,30)>25;{最近30个周期有25个以上周期满足OBV位于MAOBV和1.03倍MAOBV之间}

A2:=EVERY(OBV>MAOBV,5);{最近5个周期都满足OBV大于MAOBV}

A3:=CROSS(DIF,DEA);{DIF、DEA金叉}

AA:=A1 AND A2 AND A3;

DRAWICON(AA,DIF,1);

三、MACD与OBV结合选股公式

DIF:=EMA(C,12)-EMA(C,26);

DEA:=EMA(DIF,9);

MACD:=(DIF-DEA)*2;

VA:=IF(C>REF(C,1),VOL,-VOL);

OBV:=SUM(IF(C=REF(C,1),0,VA),0);

MAOBV:=MA(OBV,30);

OBVTJ:=BETWEEN(OBV,MAOBV,MAOBV*1.03);{OBV位于MAOBV和1.03倍MAOBV之间}

A1:=COUNT(OBVTJ,30)>25;{最近30个周期有25个以上周期满足OBV位于MAOBV和1.03倍MAOBV之间}

A2:=EVERY(OBV>MAOBV,5);{最近5个周期都满足OBV大于MAOBV}

A3:=CROSS(DIF,DEA);{DIF、DEA金叉}

AA:=A1 AND A2 AND A3 ;

XG:FILTER(AA,10);

 关注技术Pie，学习更多通达信指标公式编写知识。

友情提醒：本文仅供学习交流技术指标公式，不构成任何投资建议。投资有风险，入市需谨慎！